# Trim [AHK_L 31+]

Trims characters from the beginning and/or end of a string.

    Result :=  Trim(String, OmitChars = " `t")
    Result := LTrim(String, OmitChars = " `t")
    Result := RTrim(String, OmitChars = " `t")

### Parameters

String | Any string value or variable. Numbers are not supported.
OmitChars | An optional list of characters (case sensitive) to exclude from the beginning and/or end of String. If omitted, spaces and tabs will be removed.

### Examples

    text := "  text  "
    MsgBox % "No trim:`t '" text "'"
        . "`nTrim:`t '" Trim(text) "'"
        . "`nLTrim:`t '" LTrim(text) "'"
        . "`nRTrim:`t '" RTrim(text) "'"
    MsgBox % LTrim("00000123","0")