# IfWinExist / IfWinNotExist / WinExist

Checks if the specified window exists.

    IfWinExist [, WinTitle, WinText,  ExcludeTitle, ExcludeText]
    IfWinNotExist [, WinTitle, WinText, ExcludeTitle, ExcludeText]
    UniqueID := WinExist("WinTitle", "WinText", "ExcludeTitle", "ExcludeText")

### Parameters

WinTitle | A window title or other criteria identifying the target window. See WinTitle.
WinText | If present, this parameter must be a substring from a single text element of the target window (as revealed by the included Window Spy utility). Hidden text elements are detected if DetectHiddenText is ON.
ExcludeTitle | Windows whose titles include this value will not be considered. Note: Due to backward compatibility, this parameter will be interpreted as a command if it exactly matches the name of a command. To work around this, use the WinExist() function instead.
ExcludeText | Windows whose text include this value will not be considered.

### Remarks

If all parameters are omitted, the Last Found Window will be checked to see if it still exists (or doesn't exist in the case of IfWinNotExist).

If either of these commands determines that a qualified window exists, the Last Found Window will be updated to be that window. In other words, if IfWinExist evaluates to true or IfWinNotExist evaluates to false, the Last Found Window will be updated.

The function WinExist() returns the Unique ID (HWND) of the first matching window (0 if none). Since all non-zero numbers are seen as "true", the statement `if WinExist("WinTitle")` is true whenever WinTitle exists.

To discover the HWND of a control (for use with Post/SendMessage or DllCall), use ControlGet Hwnd or MouseGetPos.

SetWinDelay does not apply to IfWinExist/IfWinActive.

Window titles and text are case sensitive. Hidden windows are not detected unless DetectHiddenWindows has been turned on.

### Related

IfWinActive, SetTitleMatchMode, DetectHiddenWindows, Last Found Window, Process, WinActivate, WinWaitActive, WinWait, WinWaitClose, #IfWinActive/Exist

### Examples

    ; Example 1
    IfWinExist, Untitled - Notepad
    {
        WinActivate  ; Automatically uses the window found above.
        WinMaximize  ; same
        Send, Some text.{Enter}
        return
    }

    ; Example 2
    IfWinNotExist, Calculator
        return
    else
    {
        WinActivate  ; The above "IfWinNotExist" also set the "last found" window for us.
        WinMove, 40, 40  ; Move it to a new position.
        return
    }

    ; Example 3
    if WinExist("ahk_class Notepad") or WinExist("ahk_class" . ClassName)
        WinActivate  ; Uses the last found window.

    MsgBox % "The active window's ID is " . WinExist("A")

    ; Example 4: Equivalent to IfWinNotExist, Calculator
    If !WinExist("Calculator")
        return