symmetricPower(ZZ,LabeledModule) -- Symmetric power of a @TO LabeledModule@

Synopsis

Usage:
E = symmetricPower(i,M)
Function: symmetricPower
Inputs:
- i, an integer
- M, a free module with labeled basis
Outputs:
- E, a free module with labeled basis

Description

This produces the symmetric power of a labeled module as a labeled module with the natural basis list. For instance if M is a labeled module with basis list L, then exteriorPower(2,M) is a labeled module with basis list multiSubsets(2,L) and with M as an underlying module,

i1 : S=ZZ/101[x,y,z];

i2 : M=labeledModule(S^3);

o2 : free S-module with labeled basis

i3 : F=symmetricPower(2,M)

      6
o3 = S

o3 : free S-module with labeled basis

i4 : basisList F

o4 = {{0, 0}, {0, 1}, {1, 1}, {0, 2}, {1, 2}, {2, 2}}

o4 : List

i5 : underlyingModules F

       3
o5 = {S }

o5 : List

i6 : G=symmetricPower(2,F);

o6 : free S-module with labeled basis

i7 : basisList G

o7 = {{{0, 0}, {0, 0}}, {{0, 0}, {0, 1}}, {{0, 1}, {0, 1}}, {{0, 0}, {1, 1}},
     ------------------------------------------------------------------------
     {{0, 1}, {1, 1}}, {{1, 1}, {1, 1}}, {{0, 0}, {0, 2}}, {{0, 1}, {0, 2}},
     ------------------------------------------------------------------------
     {{1, 1}, {0, 2}}, {{0, 2}, {0, 2}}, {{0, 0}, {1, 2}}, {{0, 1}, {1, 2}},
     ------------------------------------------------------------------------
     {{1, 1}, {1, 2}}, {{0, 2}, {1, 2}}, {{1, 2}, {1, 2}}, {{0, 0}, {2, 2}},
     ------------------------------------------------------------------------
     {{0, 1}, {2, 2}}, {{1, 1}, {2, 2}}, {{0, 2}, {2, 2}}, {{1, 2}, {2, 2}},
     ------------------------------------------------------------------------
     {{2, 2}, {2, 2}}}

o7 : List

The first symmetric power of a labeled module is not the identity in the category of labeled modules. For instance, if M is a free labeled module with basis list {0,1} and with no underlying modules, then symmetricPower(1,M) is a labeled module with basis list {{0}, {1},} and with M as an underlying module.

i8 : S=ZZ/101[x,y,z];

i9 : M=labeledModule(S^2);

o9 : free S-module with labeled basis

i10 : E=symmetricPower(1,M);

o10 : free S-module with labeled basis

i11 : basisList M

o11 = {0, 1}

o11 : List

i12 : basisList E

o12 = {{0}, {1}}

o12 : List

i13 : underlyingModules M

o13 = {}

o13 : List

i14 : underlyingModules E

        2
o14 = {S }

o14 : List

By convention, the zeroeth symmetric power of an S-module is the labeled module S¹ with basis list {{}} and with no underlying modules.

i15 : S=ZZ/101[x,y,z];

i16 : M=labeledModule(S^2);

o16 : free S-module with labeled basis

i17 : E=symmetricPower(0,M)

       1
o17 = S

o17 : free S-module with labeled basis

i18 : basisList E

o18 = {{}}

o18 : List

i19 : underlyingModules E

o19 = {}

o19 : List