next | previous | forward | backward | up | top | index | toc | Macaulay2 web site
NormalToricVarieties :: toricDivisor(NormalToricVariety)

toricDivisor(NormalToricVariety) -- make the canonical divisor

Synopsis

Description

On a smooth normal toric variety, the canonical divisor equals minus the sum of all the torus-invariant prime divisors. For a singular toric variety, this divisor may not be Cartier or even QQ-Cartier. Nevertheless, the associated coherent sheaf, whose local sections are rational functions with at least simple zeros along the prime divisors, is the dualizing sheaf.

The first example illustrates the canonical divisor on projective space

i1 : PP3 = projectiveSpace 3;
i2 : K = toricDivisor PP3

o2 = - D  - D  - D  - D
        0    1    2    3

o2 : ToricDivisor on PP3
i3 : omega = OO K

          1
o3 = OO    (-4)
       PP3

o3 : coherent sheaf on PP3
i4 : HH^3(PP3, OO_PP3(-7) ** omega)

       120
o4 = QQ

o4 : QQ-module, free
i5 : HH^0(PP3, OO_PP3(7))

       120
o5 = QQ

o5 : QQ-module, free
The second example illustrates that duality also holds on complete singular nonprojective toric varieties.
i6 : Rho = {{-1,-1,1},{3,-1,1},{0,0,1},{1,0,1},{0,1,1},{-1,3,1},{0,0,-1}};
i7 : Sigma = {{0,1,3},{0,1,6},{0,2,3},{0,2,5},{0,5,6},{1,3,4},{1,4,5},{1,5,6},{2,3,4},{2,4,5}};
i8 : X = normalToricVariety(Rho,Sigma);
i9 : isSmooth X

o9 = false
i10 : isComplete X    

o10 = true
i11 : isProjective X

o11 = true
i12 : K = toricDivisor X    

o12 = - D  - D  - D  - D  - D  - D  - D
         0    1    2    3    4    5    6

o12 : ToricDivisor on X
i13 : isCartier K

o13 = true
i14 : omega = OO K

         1
o14 = OO  (2,-2,-8,-8)
        X

o14 : coherent sheaf on X
i15 : HH^0(X, OO_X(-1,2,4,5))

        5
o15 = QQ

o15 : QQ-module, free
i16 : HH^3(X, OO_X(1,-2,-4,-5) ** omega)

        5
o16 = QQ

o16 : QQ-module, free

See also