next | previous | forward | backward | up | top | index | toc | Macaulay2 web site
NormalToricVarieties :: fromCDivToWDiv

fromCDivToWDiv -- get the map from Cartier divisors to Weil divisors

Synopsis

Description

The group of torus-invariant Cartier divisors is the subgroup of all locally principal torus-invariant Weil divisors.

On a smooth normal toric variety, every torus-invariant Weil divisor is Cartier, so the inclusion map is simply the identity map.

i1 : PP2 = projectiveSpace 2;
i2 : cDiv PP2

       3
o2 = ZZ

o2 : ZZ-module, free
i3 : fromCDivToWDiv PP2

o3 = | 1 0 0 |
     | 0 1 0 |
     | 0 0 1 |

              3        3
o3 : Matrix ZZ  <--- ZZ
i4 : isSmooth PP2

o4 = true
i5 : FF1 = hirzebruchSurface 1;
i6 : cDiv FF1

       4
o6 = ZZ

o6 : ZZ-module, free
i7 : fromCDivToWDiv FF1

o7 = | 1 0 0 0 |
     | 0 1 0 0 |
     | 0 0 1 0 |
     | 0 0 0 1 |

              4        4
o7 : Matrix ZZ  <--- ZZ
i8 : isSmooth FF1

o8 = true
On a simplicial normal toric variety, every torus-invariant Weil divisor is ℚ-Cartier --- every torus-invariant Weil divisor has a positive integer multiple that is Cartier.
i9 : U = normalToricVariety({{4,-1},{0,1}},{{0,1}});
i10 : cDiv U

        2
o10 = ZZ

o10 : ZZ-module, free
i11 : wDiv U

        2
o11 = ZZ

o11 : ZZ-module, free
i12 : fromCDivToWDiv U

o12 = | 4 -1 |
      | 0 1  |

               2        2
o12 : Matrix ZZ  <--- ZZ
i13 : prune cokernel fromCDivToWDiv U

o13 = cokernel | 4 |

                               1
o13 : ZZ-module, quotient of ZZ
i14 : isSimplicial U

o14 = true
i15 : U' = normalToricVariety({{4,-1},{0,1}},{{0},{1}});
i16 : cDiv U'

        2
o16 = ZZ

o16 : ZZ-module, free
i17 : wDiv U'

        2
o17 = ZZ

o17 : ZZ-module, free
i18 : fromCDivToWDiv U'

o18 = | 1 0 |
      | 0 1 |

               2        2
o18 : Matrix ZZ  <--- ZZ
i19 : isSmooth U'

o19 = true
In general, the Cartier divisors are only a subgroup of the Weil divisors.
i20 : C = normalToricVariety({{1,0,0},{0,1,0},{0,0,1},{1,1,-1}},{{0,1,2,3}});
i21 : cDiv C

        3
o21 = ZZ

o21 : ZZ-module, free
i22 : wDiv C

        4
o22 = ZZ

o22 : ZZ-module, free
i23 : fromCDivToWDiv C

o23 = | 1 0 0  |
      | 0 1 0  |
      | 0 0 1  |
      | 1 1 -1 |

               4        3
o23 : Matrix ZZ  <--- ZZ
i24 : prune coker fromCDivToWDiv C

        1
o24 = ZZ

o24 : ZZ-module, free
i25 : isSimplicial C

o25 = false
i26 : X = normalToricVariety(id_(ZZ^3) | -id_(ZZ^3));
i27 : wDiv X

        8
o27 = ZZ

o27 : ZZ-module, free
i28 : cDiv X

        4
o28 = ZZ

o28 : ZZ-module, free
i29 : fromCDivToWDiv X

o29 = | 1  -3 1  2  |
      | 1  -3 1  0  |
      | -1 -1 1  2  |
      | -1 -1 1  0  |
      | 1  -1 -1 0  |
      | 1  -1 -1 -2 |
      | -1 1  -1 0  |
      | -1 1  -1 -2 |

               8        4
o29 : Matrix ZZ  <--- ZZ
i30 : prune cokernel fromCDivToWDiv X

o30 = cokernel | 2 0 0 |
               | 0 2 0 |
               | 0 0 2 |
               | 0 0 0 |
               | 0 0 0 |
               | 0 0 0 |
               | 0 0 0 |

                               7
o30 : ZZ-module, quotient of ZZ
i31 : isSimplicial X

o31 = false

See also

Ways to use fromCDivToWDiv :