next | previous | forward | backward | up | top | index | toc | Macaulay2 web site
NormalToricVarieties :: cotangentSheaf(NormalToricVariety)

cotangentSheaf(NormalToricVariety) -- make the sheaf of Zariski 1-forms

Synopsis

Description

For a normal variety, the sheaf of Zariski 1-forms is defined to be the double dual of the cotangent bundle or equivalently the extension of the sheaf of 1-forms on the smooth locus to the entire variety (the complement of the smooth locus has codimension at least two because the variety is normal). By construction, this sheaf is reflexive with rank equal to the dimension of the variety. When the underlying variety is smooth, this is simple the sheaf of 1-forms or the cotangent bundle.

On a non-degenerate normal toric variety, the sheaf of Zariski 1-forms is associated to the kernel of a map from the character lattice tensor the total coordinate ring to the direct sum over the rays of the quotient of the total coordinate ring by the ideal generated by the corresponding variable.

i1 : PP3 = projectiveSpace 3;
i2 : OmegaPP3 = cotangentSheaf PP3

o2 = cokernel {2} | x_2  0    0    x_3  |
              {2} | x_0  x_3  0    0    |
              {2} | -x_1 0    x_3  0    |
              {2} | 0    x_1  x_0  0    |
              {2} | 0    -x_2 0    x_0  |
              {2} | 0    0    -x_2 -x_1 |

                                             6
o2 : coherent sheaf on PP3, quotient of OO    (-2)
                                          PP3
i3 : prune exteriorPower(3,OmegaPP3)

          1
o3 = OO    (-4)
       PP3

o3 : coherent sheaf on PP3
i4 : prune exteriorPower(3,OmegaPP3) === OO toricDivisor PP3

o4 = true
i5 : X = hirzebruchSurface 2;
i6 : OmegaX = cotangentSheaf X

o6 = cokernel {2, 0}  | 2x_1x_3 |
              {-1, 2} | x_0     |
              {-1, 2} | -x_2    |

                                         1             2
o6 : coherent sheaf on X, quotient of OO  (-2,0) ++ OO  (1,-2)
                                        X             X
i7 : prune exteriorPower(dim X, OmegaX)

        1
o7 = OO  (0,-2)
       X

o7 : coherent sheaf on X
i8 : prune exteriorPower(dim X, OmegaX) === OO toricDivisor X

o8 = true
i9 : Rho = {{1,0,0},{0,1,0},{0,0,1},{0,-1,-1},{-1,0,-1},{-2,-1,0}};
i10 : Sigma = {{0,1,2},{0,1,3},{1,3,4},{1,2,4},{2,4,5},{0,2,5},{0,3,5},{3,4,5}};
i11 : Y = normalToricVariety(Rho,Sigma);
i12 : isSmooth Y

o12 = false
i13 : isProjective Y

o13 = false
i14 : OmegaY = cotangentSheaf Y

o14 = cokernel {0, 0, 2}  | x_2x_4 0      2x_0x_4 0    0      0     x_0x_2 0      0    |
               {2, 2, 0}  | x_1x_5 x_0x_5 0       0    0      0     0      x_0x_1 0    |
               {2, -3, 3} | 0      x_2x_3 -x_1x_3 0    x_1x_2 0     0      0      0    |
               {2, 0, 2}  | -x_3   0      0       x_0  0      0     0      0      0    |
               {2, -1, 3} | 0      -x_4   0       0    0      x_1   0      0      0    |
               {2, -1, 3} | 0      0      -x_5    0    0      0     0      0      x_2  |
               {2, -2, 4} | 0      0      0       -x_4 -2x_4  -2x_3 -x_3   0      0    |
               {3, -1, 3} | 0      0      0       -x_5 x_5    0     0      -x_3   -x_3 |
               {2, 0, 3}  | 0      0      0       0    0      -x_5  x_5    -x_4   2x_4 |

                                          1               1                1                1                2                1                1                1
o14 : coherent sheaf on Y, quotient of OO  (0,0,-2) ++ OO  (-2,-2,0) ++ OO  (-2,3,-3) ++ OO  (-2,0,-2) ++ OO  (-2,1,-3) ++ OO  (-2,2,-4) ++ OO  (-3,1,-3) ++ OO  (-2,0,-3)
                                         Y               Y                Y                Y                Y                Y                Y                Y
i15 : prune exteriorPower(dim Y, OmegaY)

         1
o15 = OO  (-3,1,-4)
        Y

o15 : coherent sheaf on Y
i16 : prune exteriorPower(dim Y, OmegaY) === OO toricDivisor Y    

o16 = true

See also